Loop command: against the results of another command.

      FOR /F ["options"] %%parameter IN ('command_to_process') DO command

      delims=xxx   The delimiter character(s) default: a Space, TAB, comma, Equals or Semicolon.

      skip=n       A number of lines to skip at the beginning. Default = 0.

      eol=;        Character at the start of each line to indicate a comment
                   The default is a semicolon ;

      tokens=n     The numbered items to  read from each line. Default = 1.

      usebackq     Use the alternate quoting style:                        
                   - Instead of double quotes use single quotes for 'Text string to process'
                   - Use double quotes for long file names in "filenameset".
                   - Use back quotes for `command_to_process`

  command_to_process : The output of the 'command_to_process' is passed into the FOR parameter.

   command    :   The command to carry out, including any parameters. This can be a single
                  command, or if you enclose it in (brackets), several commands, one per line.

  %%parameter :  A replaceable parameter:
                 in a batch file use %%G (on the command line %G)

FOR /F processing of a command consists of reading the output from the command one line at a time and then breaking the line up into individual items of data or 'tokens'. The DO command is then executed with the parameter(s) set to the token(s) found.

FOR parameters (%%A – %%Z)

Read the main FOR introduction page for a full description of assigning the replaceable %%parameter.
FOR parameters are used in all variations of the FOR command, it is a good idea to get up to speed with writing a basic FOR command before trying the more complex FOR / F variant.

The FOR /F command is the answer to innumerable questions where you want to take the output of some command, store it in a variable (%%G) then do something with the result.

For example the PING command returns serveral lines including one like:

Packets: Sent = 4, Received = 4, Lost = 0 (0% loss),

To select that one line of output, you can search for the text "loss" (which is always present), then use the Tokens parameter to select the number of lost packets, here this is 0 but it will vary each time you run the command.

SET _cmd=ping -n 5
FOR /f "tokens=4 delims=(=" %%G IN ('%_cmd% ^|find "loss"') DO echo Result is [%%G]

The tricky part is splitting up the line of interest into the right tokens, in this case we are splitting on the characters '=' and '('
those two characters split the line into 5 chunks of text and we pull out the fourth one with "tokens=4"

By default, /F breaks up the command output at each blank space, and any blank lines are skipped.
You can override this default parsing behavior by specifying the "options" parameter. The options must be contained within "quotes"

It is possible to use the syntax on this page to parse a text file with TYPE ('Type somefile.txt') but you will get much better performance using FOR /F File contents (somefile.txt) as that will save loading TYPE.EXE.

The precedence/priority of FOR command options is: usebackq > skip > delims > eol > tokens


This option is useful when dealing with a command that already contains one or more straight quotes.
The backquote character ` is just below the ESC key on most keyboards. See the FOR /F page for other effects of usebackq.

Usebackq can be abbreviated to useback (undocumented.)


SKIP will skip processing a number of lines from the beginning of the file.
SKIP includes empty lines, but after the SKIP is complete, FOR /F ignores (does not iterate) empty lines. Some commands, in particular WMIC will append extra carriage returns to otherwise blank lines at the end of their output. To skip these, add a goto command to break out of the FOR loop.


The default end-of-line character is a semicolon ';' when the FOR command reads a text file (or even a character string), any line that STARTS with the eol character will be ignored. In other words it is treated as a comment.
Use eol=X to change the eol character to X.

Often you will want to turn this feature off so that every line of your data file is processed, in theory "eol=" should turn this feature off, but in practice this fails to work correctly - it will set eol to whatever the next character is, often the quote or space character. One workaround is to set eol to some unusual character that you don’t expect to ever encounter in the data file e.g. "eol=€" or "eol=¬". Another method is to escape every delimiter For /f tokens^=*^ delims^=^ eol^= %%a in (file.txt) do... (see forum for a discussion of this)


More than one delimiter can be specified so a string like 'abcd+efg+hijk;lmno;pqr' can be broken up using "delims=;+".

for /f "tokens=1,2,3,4,5 delims=;+" %%G in ('type filename.txt') do echo %%G %%H %%K

For simple FOR commands which only process one item at a time, use "delims="
This will place everything on the line into the first token. even if it contains spaces, e.g. a long filename.

for /f "delims=" %%G in ('dir /b C:\demo\*.*') do echo %%G

You can use almost any character as a delimiter, but they are case sensitive.

delims should always the last item in the options string "tokens=3 delims= " not "delims=  tokens=3"
This is because the quotations around the options string do double duty as a terminator for the delims character(s), which is particularly important when that character is a space.

If you don’t specify delims it will default to "delims=<tab><space>,=;"
This is the same as the default delimiters for the CMD shell command line (Space,Tab,Comma,Equals,Semicolon). All of those can be specified as individual delimiters with the FOR command, but when using = as a delimiter it cannot be the last one in the list. So this is valid: "delims=;= " and this is not valid: "delims=; ="

Consecutive delimiters will be treated as one, even if they are different characters.
This means that if any data values are missing between delimiters the subsequent items in that line will be assigned a different token, e.g.


In the first line the price will be assigned to the third token, but for the second line, the price will be assigned to the second token.
A common workaround for this issue is to pre-process the input data adding a placeholder character between any consecutive delimiters. e.g. replace ',,' with ',~,'

One special case is using a double quote (") as delimiter.
By default this will be misinterpreted as the end of the "delims string", a workaround for this is to remove the outer enclosing quotes and instead escape all the delimiter chars with ^.

for /f tokens^=1^,2^,3^ delims^=^" %%G in ('type filename.txt') do echo %%G %%H %%I

n.b. some text editors will enter the TAB character as a series of spaces.


tokens=2,4,6  Will cause the second, fourth and sixth items on each line to be processed (3 Tokens).

tokens=2-6  Will cause the second, third, fourth, fifth and sixth items on each line to be processed (5 Tokens).

tokens=*   Will cause all items on each line to be processed as a single string Token.

tokens=3*  Will process the third item as one string token and then all subsequent text as a second string Token.
This can also be written as tokens=3,*

If the last character in the tokens= string is an asterisk '*', then one additional parameter is added for all the remaining text on the line.

If an asterix is used in the tokens= string then it must be the last character in the string.

The parameter added by the asterix is based on the whole tokens= string and not on the number preceding the asterix, so if you select tokens 1,2,* the asterisk will represent the third and all subsequent items, and if you select tokens=19,2,1,* then the asterisk will represent the 20th and all subsequent items.

Each token specified will cause a corresponding parameter letter to be allocated. The letters used for tokens are case sensitive.

The following ASCII characters can be used as FOR tokens:
ASCII 63 - 93 inclusive, 31 tokens: ? @ A B C D E F G H I J K L M N O P Q R S T U V W X Y Z [ \ ]
ASCII 95-123 inclusive, 29 tokens: _ ` a b c d e f g h i j k l m n o p q r s t u v w x y z {
(there are a few other characters that can be used, but require escaping)

A single FOR /F command can never parse more than 31 tokens, to use more requires a workaround with multiple FOR commands.

The tokens selected do not have to be listed in numeric order, though it is usually more readable to do so. The numbers selected in tokens= are automatically sorted, so for example tokens=5,7,1-3 and tokens=1,2,3,5,7 both produce the same result.

Matching the same token more than once (tokens=1,2,1) can give unpredictable results. Token variables can of course be used multiple times: Echo %%G %%H %%G

FOR tokens variables (or parameter names) are global, so in complex scripts which call one FOR statement from within another FOR statement you can refer to both sets of parameters.


The command_to_process can be almost any internal or external command, but there are a few commands that have no effect when are called through FOR /F - SHIFT, SETLOCAL, ENDLOCAL, CALL:Subroutine.
To be clear these can be used as part of command, but not command_to_process

If the command_to_process is a long filename, you will need to surround it in double quotes, similarly any parameters with spaces need to be double quoted. In addition to that the entire command_to_process needs to be enclosed in another set of double quotes like so:

FOR /f %%G in ('""C:\Program Files\some Program.exe" "a string" "second""') do...

This is because the FOR command will start the program in a new sub-shell which removes the outer set of double quotes.

If any of the strings contain multiple consecutive delimiters (typically spaces) then you may need to escape them "before ^ ^ after" otherwise they will be merged into a single delimiter/space.


This can be almost any internal or external command.

A common pattern is to set a variable = some token output to make it available for later processing/display. When doing this be sure to read the section Using variables within a FOR loop on the main FOR page.

Also consider the case where the command fails, the FOR command will trap the error, but the DO clause is never reached - this means the variable will not be changed. This can cause subtle bugs. When using the FOR command in a batch file always use SETLOCAL at the start to localise all variables. Alternatively you can explicitly clear the variable(s) to remove any existing value, just before running the FOR loop.

FOR does not, by itself, set or clear an Errorlevel, leaving that to the command being called.
FOR is an internal command.


Select just the version number from the output of VER:

  @echo off
  For /f "tokens=3,*" %%G in ('ver') do echo The version is [%%H

How would you modify this to remove the square brackets from the output? (hint you will need a delims=).

To ECHO from the command line, the name of every environment variable.

   FOR /F "delims==" %G IN ('SET') DO @Echo %G

The same command with usebackq:

   FOR /F "usebackq delims==" %G IN (`SET`) DO @Echo %G

To put the Windows Version into an environment variable

   @echo off 
   ::parse the VER command 
   FOR /F "tokens=4*" %%G IN ('ver') DO SET _version=%%G 
   :: show the result 
   echo %_version%

List all the text files in a folder:

   FOR /F "tokens=*" %%G IN ('dir /b C:\docs\*.txt') DO echo %%G

The "tokens=*" has been added to match all parts of any long filenames returned by the DIR command.

List all the text files in a folder, including the full path:

   FOR /F "tokens=*" %%G IN ('dir /b /s ^"c:\program files\*.txt^"') DO echo %%G

We use DIR /S (even if the folder has no subfolders) to make DIR return the full path to each file.
In the example above the long filename has to be surrounded in "quotes" and those quotes have to be escaped using ^

Although the above is a trivial example, being able to set a variable equal to each long filename in turn allows much more complex processing to be done.

More examples can be found on the Syntax / Batch Files pages and the other FOR pages below.

“History never repeats itself, Mankind always does” - Voltaire

Related commands

FOR - Summary of FOR Loop commands.
FOR - Loop through a set of files in one folder.
FOR /R - Loop through files (recurse subfolders).
- Loop through several folders.
FOR /L - Loop through a range of numbers.
FOR /F - Loop through items in a text file.
SETLOCAL - Control the visibility of variables inside a FOR loop.
FORFILES - Batch process multiple files.
GOTO - Direct a batch program to jump to a labelled line.
IF - Conditionally perform a command.
Equivalent PowerShell: ForEach-Object - Loop for each object in the pipeline.
Equivalent bash command (Linux): for - Expand words, and execute commands

Copyright © 1999-2024
Some rights reserved